#include "colors.inc"
#include "woods.inc"
#include "glass.inc"

background { White }

camera {
  location <0, 5, -20>
  look_at  <0, 5,  0>
}

// Two lights, one on either side of the camera.
light_source {
  <10, 10, -10> color White
  photons {
    reflection off
    refraction on
  }
}
light_source {
  <-10, 20, -10> color White
  photons {
    reflection off
    refraction on
  }
}


// Table-top
cylinder {
  <0, 0, 0>,
  <0, 0, -0.5>,
  10
  texture { T_Wood7 scale 20 rotate <-100, 0, 45> }
  rotate -90*x
}  


// Bowl
difference {
  sphere { // Outside surface
    <0, 4, 0>, 7.25
  }

  difference {
    sphere { // Inside surface
      <0, 4, 0>, 7
    }
    box { // Chop bottom off
      <-10,-5,-10>
      <10,0.25,10>
    }
  }
  cone { // Carve out top
   <0, 4, 0>, 0
   <0, 12, 0>, 9
  }

  texture { pigment {Col_Glass_General } }
  interior { ior 1.5 } // Glass refraction
  photons {
    target
    reflection off
    refraction on
  }
}


// Water
difference {
  sphere { // Inside surface
    <0, 4, 0>, 7
  }
  box { // Chop bottom off
    <-10,-5,-10>
    <10,0.25,10>
  }
  box { // Chop top off
    <-10,7,-10>
    <10,12,10>
  }
  scale .999
  texture { pigment {Col_Glass_Clear} }
  interior { ior 1.33 } // Water refraction
  photons {
    target
    reflection off
    refraction on
  }
}


// Goldfish
box {
  <0,0,0>
  <1,1,0>
  pigment {
    image_map {
      gif "goldfish.gif"
      map_type 0
      transmit 253, 1.0 // colour 253 is our transparent background.
    }
  }
  translate <-0.5, 0.1, -1>
  scale <6, 6, 1>
  finish { ambient 0.6 } // Brighten
}


// Bubbles
sphere {
  <0, 4.5, 0>, 0.15
  texture { pigment {Col_Glass_General} }
  interior { ior 1 } // Air refraction
  finish { ambient 1 } // Brighten
}
sphere {
  <-0.5, 5.5, 0>, 0.175
  texture { pigment {Col_Glass_General} }
  interior { ior 1 } // Air refraction
  finish { ambient 0.9 } // Brighten
}
sphere {
  <0.2, 6.3, 0>, 0.2
  texture { pigment {Col_Glass_General} }
  interior { ior 1 } // Air refraction
  finish { ambient 0.8 } // Brighten
}



global_settings {
  max_trace_level 10
  photons {
    spacing 0.005
  }
}

//  texture { pigment { color Yellow}}